2016年02月18日

相変わらず動作する、vlc-2.0.8.a-1。pacbang-2016.02-i686(4.4-1-2-ARCH)

いまでも、ときどきインストールする
古いvlc。archlinux上でのバージョン2.0.8a-1。

インストールする理由:
・音が低出力で大きく出る。
・放送局のほうで番組(何らかのチャンネル?)が
 切り替えられたあとでも、音声が低くなったり、
 間延びしたりしない。
・映像も音声も全体的に安定している。
・とにかく動作が軽い。
・recpt1でなら、だんぜんコレ。

欠点:
・画面の両側に黒地の無駄なアキが出る。
 (最近のバージョンでは出ない)
・二ヶ国語放送に対応していない。

2.0.8のソースは、いまでも、vlcオフィシャルサイトにありますね。
http://download.videolan.org/pub/videolan/vlc/

ただ、absで取得した最新バージョンの
PKGBUILDファイルをかなり修正しないと、
patchも上手く当たらないし、
ビルドもできないんだろうと思います。

vlc-2.0.8.a-1を動作させるには、
libdvbpsi-1:0.2.2-1がまる必。
残りの依存パッケージは、今日の最新パッケージで
問題ないです。

vlc-2.0.8a-1が最新であった当時のPKGBUILDファイルの内容:
-------------------------------------------------------
# $Id: PKGBUILD 191972 2013-08-02 09:52:35Z bpiotrowski $
# Maintainer: Giovanni Scafora
# Contributor: Sarah Hay
# Contributor: Martin Sandsmark

pkgname=vlc
pkgver=2.0.8.a
pkgrel=1
pkgdesc="A multi-platform MPEG, VCD/DVD, and DivX player"
arch=('i686' 'x86_64')
url="http://www.videolan.org/vlc/"
license=('LGPL2.1' 'GPL2')
depends=('a52dec' 'libdvbpsi' 'libxpm' 'libdca' 'qt4' 'libproxy'
'sdl_image' 'libdvdnav' 'libtiger' 'lua51' 'libmatroska'
'zvbi' 'taglib' 'libmpcdec' 'ffmpeg-compat' 'faad2' 'libupnp'
'libshout' 'libmad' 'libmpeg2' 'xcb-util-keysyms')
makedepends=('live-media' 'libnotify' 'libbluray' 'flac' 'kdelibs'
'libdc1394' 'libavc1394' 'lirc-utils' 'libcaca' 'oss'
'librsvg' 'portaudio' 'oss' 'libgme' 'xosd' 'projectm'
'twolame' 'aalib' 'libmtp' 'libdvdcss' 'gnome-vfs'
'libgoom2' 'libtar' 'vcdimager' 'opus' 'libssh2' 'mesa')
optdepends=('avahi: for service discovery using bonjour protocol'
'libnotify: for notification plugin'
'ncurses: for ncurses interface support'
'libdvdcss: for decoding encrypted DVDs'
'lirc-utils: for lirc plugin'
'libavc1394: for devices using the 1394ta AV/C'
'libdc1394: for IEEE 1394 plugin'
'kdelibs: KDE Solid hardware integration'
'libva-vdpau-driver: vdpau back-end for nvidia'
'libva-intel-driver: back-end for intel cards'
'libbluray: for Blu-Ray support'
'flac: for Free Lossless Audio Codec plugin'
'oss: for OSS audio support'
'portaudio: for portaudio support'
'twolame: for TwoLAME mpeg2 encoder plugin'
'projectm: for ProjectM visualisation plugin'
'libcaca: for colored ASCII art video output'
'libgme: for libgme plugin'
'librsvg: for SVG plugin'
'gnome-vfs: for GNOME Virtual File System support'
'libgoom2: for libgoom plugin'
'vcdimager: navigate VCD with libvcdinfo'
'xosd: for xosd support'
'aalib: for ASCII art plugin'
'libmtp: for MTP devices support'
'smbclient: for SMB access plugin'
'libcdio: for audio CD playback support'
'ttf-freefont: for subtitle font '
'ttf-dejavu: for subtitle font'
'opus: for opus support'
'libssh2: for sftp support')
conflicts=('vlc-plugin')
replaces=('vlc-plugin')
backup=('usr/share/vlc/lua/http/.hosts'
'usr/share/vlc/lua/http/dialogs/.hosts')
options=('!libtool' '!emptydirs')
install=vlc.install
source=("http://download.videolan.org/pub/videolan/${pkgname}/${pkgver/.a}/${pkgname}-${pkgver/.a/a}.tar.xz"
vlc-2.0.7-vaapi-compat.patch
vlc-2.0.8-Fix-live555-breakage-in-last-update.patch)
md5sums=('e5000677181406d026ffe448633d1ca0'
'6df10774bb7acf20e09d6139e5c7839e'
'e592efe7bb65291a84f99cfaa3a9f8a2')

prepare() {
cd "${srcdir}/${pkgname}-${pkgver/.a}"
patch -Np1 -i "$srcdir/vlc120.diff"
patch -Np1 -i ../vlc-2.0.7-vaapi-compat.patch
patch -Np1 -i ../vlc-2.0.8-Fix-live555-breakage-in-last-update.patch

sed -i -e 's:truetype/freefont:TTF:g' modules/text_renderer/freetype.c
sed -i -e 's:truetype/ttf-dejavu:TTF:g' modules/visualization/projectm.cpp
}

build() {
cd "${srcdir}/${pkgname}-${pkgver/.a}"

CFLAGS+="-I/usr/include/samba-4.0" CPPFLAGS+="-I/usr/include/samba-4.0" \
PKG_CONFIG_PATH+="/usr/lib/ffmpeg-compat/pkgconfig" \
./configure --prefix=/usr \
--sysconfdir=/etc \
--disable-rpath \
--enable-oss \
--enable-faad \
--enable-nls \
--enable-lirc \
--enable-pvr \
--enable-ncurses \
--enable-realrtsp \
--enable-xosd \
--enable-aa \
--enable-vcdx \
--enable-upnp \
--enable-opus \
--enable-sftp \
LUAC=luac5.1 \
RCC=/usr/bin/rcc-qt4

make
}

package() {
cd "${srcdir}/${pkgname}-${pkgver/.a}"

make DESTDIR="${pkgdir}" install

for res in 16 32 48 128; do
install -D -m644 "${srcdir}/vlc-${pkgver/.a}/share/icons/${res}x${res}/vlc.png" \
"${pkgdir}/usr/share/icons/hicolor/${res}x${res}/apps/vlc.png"
done
}
-------------------------------------------------------

のところは、二ヶ国語放送対応パッチの記述。
patchファイルの含まれるup0822.zipは、
ttp://www3.wazoku.net/2sen/dtvup/ にまだ在ります。

なんどか、エラーメッセージを吐きながら、修正していけば、
ビルドできるんじゃないのかな。じぶんにはそれをやる元気はないです。
patchを当ててビルドする方法は、ブログ内を検索すれば、
出てくると思います。

2.0.8.a-1の受信表示。
old_vlc.jpg


posted by ブログ開設者 at 12:50| Comment(0) | linux | このブログの読者になる | 更新情報をチェックする